Windows Update Full Control Script

Discussion in 'other software & services' started by Mister X, Mar 9, 2016.

  1. Mister X

    Mister X Registered Member

    Joined:
    Aug 10, 2013
    Posts:
    1,764
    Location:
    Mexico
    The script first enables automatic updates, then runs the Windows Update Mini Tool (WUMT) which lets you select which updates to block (hide) or install. When you're all done close wumt and the script gives you the choice of turning off the windows update service, or leaving it on. Turning off the windows update service afterwards disables further updates and automatic update reboot. It's all fairly self-explanatory when you run the script.

    Works with any version of windows with an automatic update service, which includes: Windows 10 core/home editions, pro, and ltsb, all versions of windows 8.x, 7, Vista, and XP. Now uses Windows Update MiniTool, auto-elevates, and auto-determines x86 or x64 then runs the right version of WUMT and prevents update auto-reboot. The only way this could be better is if they'd incorporate this into WUMT so that disabling automatic updates actually works by WUMT natively without this script. Until then, enjoy!

    Put the .cmd script below and the Windows Update MiniTool in the same folder/location i.e. X:\WindowsUpdateControl. Then make a shortcut to the script.

    This utility checks for admin and asks for permission to elevate (in XP it just skips that part and keeps going), enables automatic updates, then runs the Windows Update MiniTool, and then disables automatic updates again giving you full control. No more automatic updates or update reboots. You have to reboot manually. Perfect.

    Code:
    : ********************************************************************
    : Put the .cmd script and the Windows Update MiniTool in the same
    : folder/location i.e. X:\WindowsUpdateControl.
    : *******************************************************************
    : This utility enables automatic updates,
    : then runs the Windows Update MiniTool,
    : and then disables automatic updates
    : giving you full control. No more automatic
    : update reboots.
    :::::::::::::::::::::::::::::::::::::::::
    :: Automatically check & get admin rights
    :::::::::::::::::::::::::::::::::::::::::
    @echo off
    CLS
    ECHO.
    ECHO =============================
    ECHO Running Admin shell
    ECHO =============================
    
    :checkPrivileges
    NET FILE 1>NUL 2>NUL
    if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )
    
    :getPrivileges
    if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)
    ECHO.
    ECHO **************************************
    ECHO Invoking UAC for Privilege Escalation
    ECHO **************************************
    
    setlocal DisableDelayedExpansion
    set "batchPath=%~0"
    setlocal EnableDelayedExpansion
    ECHO Set UAC = CreateObject^("Shell.Application"^) > "%temp%\OEgetPrivileges.vbs"
    ECHO args = "ELEV " >> "%temp%\OEgetPrivileges.vbs"
    ECHO For Each strArg in WScript.Arguments >> "%temp%\OEgetPrivileges.vbs"
    ECHO args = args ^& strArg ^& " "  >> "%temp%\OEgetPrivileges.vbs"
    ECHO Next >> "%temp%\OEgetPrivileges.vbs"
    ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >> "%temp%\OEgetPrivileges.vbs"
    "%SystemRoot%\System32\WScript.exe" "%temp%\OEgetPrivileges.vbs" %*
    exit /B
    
    :gotPrivileges
    if '%1'=='ELEV' shift /1
    setlocal & pushd .
    cd /d %~dp0
    
    ::::::::::::::::::::::::::::
    ::START
    ::::::::::::::::::::::::::::
    echo ******************************
    echo This utility enables automatic updates,
    echo then runs the Windows Update MiniTool,
    echo and then disables automatic updates
    echo giving you full control. No more automatic
    echo update reboots.
    echo ******************************
    @echo off
    pause
    cls
    echo *** Enabling Windows Updates ***
    @echo on
    sc config wuauserv start= auto
    net start wuauserv
    @echo off
    echo **********************************************************
    echo Press a key to run Windows Update MiniTool.
    echo Don't close this window or automatic updates will stay on!
    echo Return to this window when finished with WUMT.
    echo **********************************************************
    pause
    @echo off
    :CheckOS
    IF EXIST "%PROGRAMFILES(X86)%" (GOTO 64BIT) ELSE (GOTO 32BIT)
    :64BIT
    wumt_x64.exe
    GOTO END
    :32BIT
    wumt_x86.exe
    GOTO END
    :END
    @cls
    @echo off
    echo **************************************************
    echo Press a key to disable automatic updates (recommended), or
    echo ctrl-c to exit and leave automatic updates turned on (if you must).
    echo ***************************************************
    pause > nul
    @echo on
    sc config wuauserv start= disabled
    net stop wuauserv
    @echo off
    echo **************************
    echo Windows Update Completed.
    echo Press a key to exit.
    echo **************************
    pause > nul
    Changelog:
    http://forums.mydigitallife.info/threads/63703-Windows-Update-Full-Control-script
    All due credits to: pf100
     
  2. trott3r

    trott3r Registered Member

    Joined:
    Jan 21, 2010
    Posts:
    829
    Location:
    UK
    Thanks will have to look at it soon
     
  3. TairikuOkami

    TairikuOkami Registered Member

    Joined:
    Oct 10, 2005
    Posts:
    2,508
    Location:
    Slovakia
    I wonder, if it really does work on 10, since 10 can start disabled services.
     
  4. quietman

    quietman Registered Member

    Joined:
    Dec 27, 2014
    Posts:
    489
    Location:
    Earth .... occasionally
    Thanks for posting ..... " Neat , sweet , petite "

    I tried it in a W7 test machine and it seems to work as described .

    On a minor griping point , I noticed that after running / updating , the user option to "Change Update Settings"
    in Control Panel became " greyed-out " ( with a note about Admins .... and Group Policy ? )
    .... and I was running as Admin .

    Is this intentional ?

    If so it might be a good idea to include a user option to revert to the original scenario , prior to running wumt ,
    without having to do a reg edit here :-

    HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU
    and here
    HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\WindowsUpdate

    Or is it just me missing something obvious ? - :)
     
  5. trott3r

    trott3r Registered Member

    Joined:
    Jan 21, 2010
    Posts:
    829
    Location:
    UK
    hmm Russian? (Cyrillic?) menus for most of it.

    I get the windows updates though in xp pro sp3
     
  6. Infected

    Infected Registered Member

    Joined:
    Feb 9, 2015
    Posts:
    665
    I've never had Windows 10 re-enable disabled services, especially auto update. I have it blocked through group policy.
     
  7. TairikuOkami

    TairikuOkami Registered Member

    Joined:
    Oct 10, 2005
    Posts:
    2,508
    Location:
    Slovakia
    You need to download english or another language, unpack it and place ini in the same folder as WUMT.
     
  8. quietman

    quietman Registered Member

    Joined:
    Dec 27, 2014
    Posts:
    489
    Location:
    Earth .... occasionally
    You need the wumt_lang.ini file , and it needs to be in the same folder as wumt_x64.exe or wumt_x86.exe

    Double check after unzipping the package , and move things around as needed.

    That will solve the issue of Russian as the default language.
     
  9. TairikuOkami

    TairikuOkami Registered Member

    Joined:
    Oct 10, 2005
    Posts:
    2,508
    Location:
    Slovakia
    Windows will start essential services, when needed, no matter what setting, for example: Cryptographic Services / Microsoft Passport / Time Broker.
    I am sure, that Windows Update was amongst them in the past , at least on Home, but maybe MS let it change eventually, can not confirm it now.
     
  10. MisterB

    MisterB Registered Member

    Joined:
    May 31, 2013
    Posts:
    1,103
    Location:
    Southern Rocky Mountains USA
    The Windows update and BITS services will always be renabled on reboot in Windows 10 in my experience. It takes more than simply setting them to disabled to stop them. I do that by setting the ACLs of their associated .dll files to deny. Then they can't be restarted. I can't see this script working fully in Windows 10 but now I'm curious about the Windows update mini tool. I've figured out how to control and even disable automatic update in Windows 10 as a whole but it would be wonderful to get back the control over individual updates that earlier Windows had.
     
  11. TairikuOkami

    TairikuOkami Registered Member

    Joined:
    Oct 10, 2005
    Posts:
    2,508
    Location:
    Slovakia
    Would not be Windows Updates disabled, when the tasks are disabled?
    I have created this, but can not test it, since I have no Home version.
     
Loading...