Image For Windows

This page mentions DISM.exe not found...

https://www.terabyteunlimited.com/howto/tbwinrecmd_tutorial/

 

Thanks. Yeah, but no solution as far as i could see.

I am going to go back to the installation image for this Os and see if it works then. Back in a jiffy.

 

Well, now it worked to create a Wim and to restore. This Pc has not liked the disc change all day long.
On top of that It is something with the default Asus programs that creates problems if i remove them, even their repair shop said that it would create problems of i did. It is really bad when one does not own once pc fully,because of bloat that is deeply built in to the pc.

Anyhow, as always, thanks for your attention.

 

If you are interested you could install BootIt UEFI and install a fresh Win10 or Win11. Just a basic install. Dual boot. See If IFW and Macrium work properly in the fresh install without Asus apps.

 

It works ok now so what would be the purpose with that?

 

That article makes it sound complicated. All you need to do is right click on the Offline icon and click Online.
With a GPT disk, this does not change the Disk ID. It changes the Device and Partition GUIDs. With a MBR disk, the Disk ID is changed.

 

OK

 

The item with the Asus apps i have checked and tested in all sorts of ways, even with fresh install where their install was blocked. There is some sort of symbiosis between the asus bios and the apps so when the apps is non-present, the machine is a bit, sort of unstable. The first sign was when i reinstalled Windows on it and then removed the factory partition, after that i lost the mouse in recovery environment for good. i had to buy anexternal mouse.

But i will check out BootIt and see what it is all about.

 

Your system sounds complicated. I haven't seen those issues.

Having a dual boot might not help. It was just one of those sudden thoughts. But you are familiar with your system and I'm not.

 

I use one risky software that sometimes creates problems, NTLite.
I think it might be that which caused the problem because now i got it again and that after removing stuff with it. So now i have to chase it down.

A question, do you use Edge browser?

 

I'm a Firefox user.

Maybe a dual boot could suit you. One safe OS where you don't experiment and an experimental OS. If the latter OS causes problems, restore an earlier image.
You will always have a safe OS.

 

With BootIt UEFI you can copy your current OS in minutes. Then you can do what you like to the copy.

Edit... I just copied my Win11 in 60 seconds. A Boot Item is added to the Boot Menu.

 

You mount a copy of it or what?

 

The Win11 partition is copied in BootIt. Now you have 2 Win11 partitions. Booting files are created in the EFI System partition. You can boot into either OS from the BootIt UEFI Boot Menu.

 

Aha, Boot... it, ok, i understand.
I will take a look tomorrow, not it is way over bedtime in sweden.

Godnight

 

1213 here

 

@Brian K

I have the same problem again as in post #1624. I can not get rid of IFW bootmenu.

When creating WinRE there are several option to choose from, one is to set WinRE to default, that box is greyed out. I guess it should work to remove the menu if it was not, so, how to make it active?

 

pb1,

Can you post a screenshot of that menu?

Is that "Restore the original Windows Recovery Environment (WinRE)"?
If you can't select that choice I suggest you post your question in the TeraByte Unlimited forum.

 

I restored to an installation image so no screenshoot. But it is the usual one, with everything down in the left corner working but totally without the small frame above to the left to open and handle IFW.

Yes that is the one, that should have solved it, right?
I will probably post there to see what the solution is to greyed out options.

This was on a untampered Os, as is, only windows bloat removed.

 

@Brian K
Hi Brian.
I haven't visited the IFWRotate script in awhile.
Where in the script do you select the drive to be backed up?
I can see the destination drive and path where backups are to be saved, but not the drive to be backed up.

 

Here's no slightly modified rotate script for IFW. The part you're looking for is contained in the line "
set TBIParms=/b /d:w2@0x1,0x2,0x3,0x4,0x5 /opwassword /log:0 /comp:12 /min /enc:3 /nt /geoa2k /hash /usemd"
and is w2@0x1,0x2,0x3,0x4,0x5. This includes multiple partitions on one drive.

Code:

@echo off

:: Copyright (C) 2011-2012, TeraByte Unlimited.  All rights reserved.
:: version 1.2

:: This batch file maintains multiple iterations of a particular backup.  Each
:: time the batch file is run, a backup will be created. The filename will
:: include the date and time. For example, the first time the batch file is run,
:: <file name>_2010-04-18-2315__FULL.tbi will be created.  On the next run,
:: <file name>_2010-04-19-2315__FULL.tbi will be created. (Assuming it's run the
:: next day at the same time.) Once the number of backups reaches the number
:: specified, the oldest backup (or backup set) is deleted.
::
::
:: There are several settings you need to specify below.
:: Each one is preceded by the "set" command.

:: ---------------------------------------------------------------------------

:: Specify the folder where backup files will be saved. In all cases, omit the
:: trailing backslash, even for root directories (e.g. C: or D:). Folder
:: path can include spaces.
::
:: A UNC path can also be specified for this variable. NOTE: Make sure the share
:: is accessible or IFWRotate and/or Image for Windows may not function as expected.
:: If necessary, use the TBILogin variable below to specify the network share
:: login details. If IFWRotate cannot access the path it will be unable to count the
:: previous image backups, which will result in only Full images being created and
:: no images being deleted. In this case, it may be necessary to add credentials
:: for the share to the user account running IFWRotate.
::
:: Example: set TBIBase=D:\My Backups
::
:: Example: set TBIBase=\\server\backups\mybackups

set TBIBase=D:\Backups\System



:: Specify the desired backup filename below. In all cases, omit
:: the file extension. Filename can include spaces. This is the "base"
:: filename used for creating the Full and Differential filenames.
::
:: Backup images will have the same "base" name as the specified TBIName value
:: with the date, time, and "__FULL" appended (for Full images) or "_DIFF_", date,
:: and time appended (for Differential images).
::
:: Created Full image filename example: WorkComputer_2010-04-20-1754__FULL.tbi
::
:: Created Differential image filename example: WorkComputer_2010-04-20-1754_DIFF_2010-04-21-1754.tbi
::
:: Example: set TBIName=WorkComputer

set TBIName=System



:: Specify the parameters that should be used by IFW below. This is
:: where you specify the source drive and partition for the backup. Do not
:: include the "/f" option. It will be included automatically.
::
:: Note: If you need to use the Image for Windows "/login" option to access a network share,
:: use the TBILogin script variable below instead of specifying /login here.
::
:: Example: set TBIParms=/b /d:w0@0x1

set TBIParms=/b /d:w2@0x1,0x2,0x3,0x4,0x5 /opw:password /log:0 /comp:12 /min /enc:3 /nt /geoa2k /hash /usemd



:: Specify the path to Image for Windows (imagew64.exe).
:: Note: Set this path only if not using the default installation path.
:: Do not include a trailing backslash. Do not include any spaces before or after the equals sign.
:: Omit quotation marks and the trailing backslash.
::
:: Example: set TBIPath=C:\Program Files (x86)\TeraByte Drive Image Backup and Restore Suite

set TBIPath=C:\Program Files\IFW



:: Specify the maximum number of Full image files to be saved. The oldest
:: Full image file (along with any associated Differential images) will be
:: deleted when this value is exceeded. Number must be between 2 and 99.
::
:: Note: If the number of existing backup sets (Fulls or Fulls + Differentials) exceed
:: the number specified, the older sets will be deleted when a new Full is created.
:: This may result in multiple sets being deleted. For example, if you had a previous
:: maximum of 7 and changed it to 3, the oldest sets will be deleted to bring
:: the count down to the new maximum of 3 when a new Full is created.
::
:: Example: Set TBIMaxFullCnt=4

set TBIMaxFullCnt=10



:: Specify the maximum number of Differential image backups to be created for
:: each Full backup. A setting of 0 (zero) will create only Full image backups.
:: If you want to create Differential backups, set the value to 1 or higher (max. 99).
::
:: Example: set TBIMaxDiffCnt=6

set TBIMaxDiffCnt=6



:: Specify any parameters needed when creating a Differential backup. Don't
:: include the "/b", "/base", or "/f" options as those are automatically
:: included. For example, you may want to verify the image after it's created.
::
:: Note: If you need to use the Image for Windows "/login" option to access a network share,
:: use the TBILogin script variable below instead of specifying /login here.
::
:: Example: set TBIDifParms=/v
::

set TBIDifParms=/opw:password /log:0 /comp:12 /min /enc:3 /nt /geoa2k /hash /usemd



:: Specify the network login details (if needed to access a network share). Do not set
:: if network login is not required.
::
:: If you include the login details here, don't include them in TBIParms or TBIDifParms.
:: See the Image for Windows manual for details using the /login parameter.
::
:: Note: When this variable is used the script must be run with administrator privileges.
::
:: Example: set TBILogin=/login:"\\server\share*username*password"
:: Example: set TBILogin=/login:"\\BackupServer\Win7Backups*JohnSmith*mypassword"

set TBILogin=



:: ====================================================
:: Command line options for this script file
:: ====================================================
::
:: /f   Forces a new Full image to be created. Rotation rules for the
::      maximum number of Full images will still be enforced.
::
:: /d   Forces a new Differential image to be created. Using this option
::      will create a Differential image even if it will exceed the maximum
::      number specified.
::
::      Note: The Differential image will be based on the newest Full image.
::      If no Full image exists, a Full image will be created instead.
::
::

:: ###########################################################################
:: #
:: # NO CHANGES SHOULD BE NEEDED PAST THIS POINT
:: #
:: ###########################################################################

:: Check for Windows 2000 or later

if not "%OS%"=="Windows_NT" goto :NoWin

:: ---------------------------------------------------------------------------

:: Init vars

setlocal enableextensions enabledelayedexpansion

set Error=X
set Number1=X
set Number2=X
set TBICmd=X
set TBIOldest=X
set TBINewest=X

if %TBIMaxFullCnt% LSS 2 set /a TBIMaxFullCnt=2
if %TBIMaxFullCnt% GTR 99 set /a TBIMaxFullCnt=99
if %TBIMaxDiffCnt% LSS 0 set /a TBIMaxDiffCnt=0
if %TBIMaxDiffCnt% GTR 99 set /a TBIMaxDiffCnt=99

if not defined TBIBase echo No TBIBase parameter supplied.  Please edit: %0 & goto :End
if not defined TBIName echo No TBIName parameter supplied.  Please edit: %0 & goto :End
if not defined TBIParms echo No TBIParms parameter supplied.  Please edit: %0 & goto :End
if not defined TBIMaxFullCnt echo No TBIMaxFullCnt parameter supplied.  Please edit: %0 & goto :End
if not defined TBIMaxDiffCnt echo No TBIMaxDiffCnt parameter supplied.  Please edit: %0 & goto :End

:: ---------------------------------------------------------------------------

if "%TBIPath:~0,1%"==" " (set TBIPath=)
if "%TBIPath%"=="" if "%PROCESSOR_ARCHITECTURE%"=="AMD64" set TBIPath=C:\Program Files (x86)\TeraByte Drive Image Backup and Restore Suite
if "%TBIPath%"=="" set TBIPath=C:\Program Files\TeraByte Drive Image Backup and Restore Suite
if not exist "%TBIPath%\imagew64.exe" echo Unable to find 'imagew64.exe' in the following path: & echo %TBIPath% & echo. & echo Please edit %0 and check TBIPath value. & goto :End

:: ---------------------------------------------------------------------------

:: Log into network share

if "%TBILogin:~0,1%"==" " (set TBILogin=)
if defined TBILogin start "" /min /wait "%TBIPath%\imagew64.exe" %TBILogin% /log:0 /quit

:: Get Full image file counts

set /a Number1=0
if exist "%TBIBase%\%TBIName%_*__FULL.tbi" for /f "delims=" %%a in ('dir "%TBIBase%\%TBIName%_*__FULL.tbi" /o-d /b /p /-p /w /-w') do (set TBIOldest=%%a) & (set /a Number1=!Number1!+1) & (if "!TBINewest!"=="X" set TBINewest=%%a)
set TBIFullCnt=%Number1%
echo.
echo Number of Full images found in set: %TBIFullCnt%
if "%TBINewest%"=="X" set TBINewest=(none)
if "%TBIOldest%"=="X" set TBIOldest=(none)
echo Oldest Full image set found: %TBIOldest%
echo Newest Full image set found: %TBINewest%

:: Get Diff image file counts for newest set

set TBINewest=%TBINewest:~0,-10%
set /a Number1=0
if exist "%TBIBase%\%TBINewest%_DIFF*.tbi" for /f %%a in ('dir "%TBIBase%\%TBINewest%_DIFF*.tbi" /o-d /b /p /-p /w /-w') do (set /a Number1=!Number1!+1)
set TBIDiffCnt=%Number1%
echo.
echo Number of Differential images found in newest Full set: %TBIDiffCnt% of %TBIMaxDiffCnt%

:: Check which type of backup (Full or Diff) needs to be created

if /i "%1"=="/f" goto :CreateFull
if %TBIFullCnt%==0 goto :CreateFull
if /i "%1"=="/d" goto :CreateDiff
if %TBIDiffCnt% LSS %TBIMaxDiffCnt% goto :CreateDiff

goto :CreateFull

:CreateDiff

echo.
echo Create Differential Image
echo -- Running command: "%TBIPath%\imagew64.exe" /b %TBIDifParms% /base:"%TBIBase%\%TBINewest%__FULL" /f:"%TBIBase%\%TBINewest%_DIFF_$~YYYY$-$~MM$-$~DD$-$~HHMM$"
start "" /wait "%TBIPath%\imagew64.exe" /b %TBIDifParms% /base:"%TBIBase%\%TBINewest%__FULL" /f:"%TBIBase%\%TBINewest%_DIFF_$~YYYY$-$~MM$-$~DD$-$~HHMM$"
goto :PostBkup

:CreateFull

if %TBIFullCnt% LSS %TBIMaxFullCnt% goto :CreateFullImage
echo.
echo Number of Full images will exceed %TBIMaxFullCnt%.
echo Deleting oldest Full image set: %TBIOldest%
del "%TBIBase%\%TBIOldest%"
set TBIOldest=%TBIOldest:~0,-10%
if exist "%TBIBase%\%TBIOldest%_DIFF*.tbi" del "%TBIBase%\%TBIOldest%_DIFF*.tbi"
if exist "%TBIBase%\%TBIOldest%__FULL.#*" del "%TBIBase%\%TBIOldest%__FULL.#*"
:: Check if additional old backup sets need deleted
set /a Number1=0
if exist "%TBIBase%\%TBIName%_*__FULL.tbi" for /f "delims=" %%a in ('dir "%TBIBase%\%TBIName%_*__FULL.tbi" /o-d /b /p /-p /w /-w') do (set TBIOldest=%%a) & (set /a Number1=!Number1!+1)
set TBIFullCnt=%Number1%
if %TBIFullCnt% LSS %TBIMaxFullCnt% goto :CreateFullImage
goto :CreateFull


:CreateFullImage

echo.
echo Create Full Image
echo -- Running command: "%TBIPath%\imagew64.exe" %TBIParms% /f:"%TBIBase%\%TBIName%_$~YYYY$-$~MM$-$~DD$-$~HHMM$__FULL"
start "" /wait "%TBIPath%\imagew64.exe" %TBIParms% /f:"%TBIBase%\%TBIName%_$~YYYY$-$~MM$-$~DD$-$~HHMM$__FULL"

forfiles -p D:\Backups\System\  -m *DIFF*.* /D -6 /C "cmd /c del /q @path"

goto :PostBkup


:: ---------------------------------------------------------------------------

:PostBkup

set Error=%ERRORLEVEL%

echo.
echo #########################################
if not "%Error%"=="0" echo # The following error was reported: %Error%
if "%Error%"=="0" echo # No errors were reported.
echo #########################################
echo.

goto :End


:: ---------------------------------------------------------------------------

:NoWin

echo.
echo Windows 2000 or later is required for this script.
echo.
goto :End


:: ---------------------------------------------------------------------------

:End

set Error=
set Number1=
set Number2=
set TBIFullCnt=
set TBIDiffCnt=
set TBICmd=
set TBIOldest=
set TBINewest=

endlocal

set TBIBase=
set TBIName=
set TBIParms=
set TBIPath=
set TBIMaxFullCnt=
set TBIMaxDiffCnt=
set TBIDifParms=
set TBILogin=

attrib +h D:\Backups\System\*.#_# /s /d

attrib +h D:\Backups\System\*.@0 /s /d

attrib +h D:\Backups\System\*.#0 /s /d

:: End of batch script

echo Done!

 

Smiley removed:

Here's no slightly modified rotate script for IFW. The part you're looking for is contained in the line "
set TBIParms=/b /d:w2@0x1,0x2,0x3,0x4,0x5 /opw:password /log:0 /comp:12 /min /enc:3 /nt /geoa2k /hash /usemd"
and is w2@0x1,0x2,0x3,0x4,0x5. This includes multiple partitions on one drive.

 

Thanks, guys.
So, it appears that /d:w0 is the disk number, where 0 is the disk number to be backed up.

I ran Image for Windows, set up the Full backup how I wanted, then used the "Show Command" button to view the parameters.

So, disk 2 would be /d:w2.

 

This problem turned out to be due to Macrium not totally erasing the usb that i did the recovery media on. First i had used it for IFW, later on for Macrium, so when booting with it as Macrium media, it also showed IFW boot screen in the background. Redoing the media for MR, but first erase and format it with Windows, did it. No IFW boot screen.

Strange that MR did not erase it fully, it even warns about doing that when creating the media.

 

I've noticed in the last couple of versions of IFW that when I boot into TBWinRE, the background goes black.
IFW is visible. So is TBLauncher. All the apps that I open from TBLauncher also display fine.

I changed the resolution from 1280 x 1024 (I think) to 1920 x 1080, which is my monitor's recommended display setting.
It took about a minute for the display to change, and the background appeared.

So, I'm thinking that the default resolution doesn't suit my monitor on one of my computers.

I see in TBWinPE.ini, that there is this setting. ScreenResolution=-m3
I don't know what that means, and I can't find any information about it.

Any ideas?