Windows Intelligence update Issue

In Windows Update ( Windows 11 Home 23H2 ) I see a Windows Intelligence update available, but I can't download it, every times Windows Update says: " installation error 0x00000000 "; how can I solve ? Alternatively I checked Microsoft update catalog, But I'm not sure which is the right manual update for me.

 

I tried after your post, it doesn't work.

 

Tried also: windows update troubleshooting, dism and sfc/scannow no results.

 

Thank you, Stapp ! I also searched with Google but nothing seems work for me and for other users. Now I'll see if I can find a manually update.

 

My problem is to find the updates number for Microsoft Catalog.

 

there exist no entry for "Windows Intelligence update", in fact for 3 or more daily updates this would spam the box.

the KB is kb2267602 and its a number for ages of updates, means in may, september, october, maybe quite earlier than those. it wont help you out, there exist no download source.

depending of your posts here you have a lot issues concerning windows security, eg
https://www.wilderssecurity.com/threads/windows-defender-scan-issue.452320/#post-3161303
you discontinued help there and i think you refused to repair windows or use a backup.
i consider this one as a sequel to that. either you deal with the issue, or start repairing or recovering.

 

thank you, i alreay read that thread today, but i missed that line, considering it as a signature.
fingers crossed this will help him out, but i have doubt, sorry.

 

Probably you are right, I should make a complete new installation of 11, and I never find the time to do it.

 

I read all. The exe that I downloaded from Microsoft link doesn't work. I read in Virus and Threat protection/About, it doesn't help me. I read also the Protection Cronology and I found this in every times I tried to launch the Windows Intelligence update " access to protected memory blocked ".

 

Should I do a complete clean reinstallation, without keep my personal data and my applications ?

 

from he link stapp gave us

if that all failed, in special dism, then you should consider a repair from usb stick - this one should meet your build from "winver".
(my latest is "Windows 11 22631.2428" which was created with the MCT)

i dont have experience with repair, but i know how to do an inplace upgrade from stick.

 

@blacknight have you tried running this as a batch script?

Code:

cd %ProgramFiles%\Windows Defender
MpCmdRun.exe -removedefinitions -dynamicsignatures
MpCmdRun.exe -SignatureUpdate

If trying the above is unsuccessful then either a repair install (See 11 Forum tutorial) or a clean install, in which case wiping the disk completely is the best bet.

 

Do you have the Windows Defender disabled by any chance?

 

No, it runs.

 

Tried now, no effect. Yes, I too believe that the only solution now is a clean install, but in my drive I have three partitions which lots of data, and I hate format the whole disk and then to have to create all them again.

 

Before you format, try this, open a blank notepad text file, copy/paste the below code:

Code:

@echo off

:: Created by: Shawn Brink
:: Created on: January 6, 2022
:: Tutorial: https://www.elevenforum.com/t/reset-windows-update-in-windows-11.3808/


:: Prompt to Run as administrator
Set "Variable=0" & if exist "%temp%\getadmin.vbs" del "%temp%\getadmin.vbs"
fsutil dirty query %systemdrive%  >nul 2>&1 && goto :(Privileges_got)
If "%1"=="%Variable%" (echo. &echo. Please right-click on the file and select &echo. "Run as administrator". &echo. Press any key to exit. &pause>nul 2>&1& exit)
cmd /u /c echo Set UAC = CreateObject^("Shell.Application"^) : UAC.ShellExecute "%~0", "%Variable%", "", "runas", 1 > "%temp%\getadmin.vbs"&cscript //nologo "%temp%\getadmin.vbs" & exit
:(Privileges_got)

:: Checking and Stopping the Windows Update services
set b=0

:bits
set /a b=%b%+1
if %b% equ 3 (
   goto end1
)
net stop bits
echo Checking the bits service status.
sc query bits | findstr /I /C:"STOPPED"
if not %errorlevel%==0 (
    goto bits
)
goto loop2

:end1
cls
echo.
echo Cannot reset Windows Update since "Background Intelligent Transfer Service" (bits) service failed to stop. Please restart the computer, and try again.
echo.
pause
goto Start


:loop2
set w=0

:wuauserv
set /a w=%w%+1
if %w% equ 3 (
   goto end2
)
net stop wuauserv
echo Checking the wuauserv service status.
sc query wuauserv | findstr /I /C:"STOPPED"
if not %errorlevel%==0 (
    goto wuauserv
)
goto loop3

:end2
cls
echo.
echo Cannot reset Windows Update since "Windows Update" (wuauserv) service failed to stop. Please restart the computer, and try again.
echo.
pause
goto Start



:loop3
set c=0

:cryptsvc
set /a c=%c%+1
if %c% equ 3 (
   goto end4
)
net stop cryptsvc
echo Checking the cryptsvc service status.
sc query cryptsvc | findstr /I /C:"STOPPED"
if not %errorlevel%==0 (
    goto cryptsvc
)
goto Reset

:end4
cls
echo.
echo Cannot reset Windows Update since "Cryptographic Services" (cryptsvc) service failed to stop. Please restart the computer, and try again.
echo.
pause
goto Start


:Reset
Ipconfig /flushdns
del /s /q /f "%ALLUSERSPROFILE%\Application Data\Microsoft\Network\Downloader\qmgr*.dat"
del /s /q /f "%ALLUSERSPROFILE%\Microsoft\Network\Downloader\qmgr*.dat"
del /s /q /f "%SYSTEMROOT%\Logs\WindowsUpdate\*"


if exist "%SYSTEMROOT%\winsxs\pending.xml.bak" del /s /q /f "%SYSTEMROOT%\winsxs\pending.xml.bak"
if exist "%SYSTEMROOT%\winsxs\pending.xml" (
    takeown /f "%SYSTEMROOT%\winsxs\pending.xml"
    attrib -r -s -h /s /d "%SYSTEMROOT%\winsxs\pending.xml"
    ren "%SYSTEMROOT%\winsxs\pending.xml" pending.xml.bak
)
 
if exist "%SYSTEMROOT%\SoftwareDistribution\DataStore.bak" rmdir /s /q "%SYSTEMROOT%\SoftwareDistribution\DataStore.bak"
if exist "%SYSTEMROOT%\SoftwareDistribution\DataStore" (
    attrib -r -s -h /s /d "%SYSTEMROOT%\SoftwareDistribution\DataStore"
    ren "%SYSTEMROOT%\SoftwareDistribution\DataStore" DataStore.bak
)

if exist "%SYSTEMROOT%\SoftwareDistribution\Download.bak" rmdir /s /q "%SYSTEMROOT%\SoftwareDistribution\Download.bak"
if exist "%SYSTEMROOT%\SoftwareDistribution\Download" (
    attrib -r -s -h /s /d "%SYSTEMROOT%\SoftwareDistribution\Download"
    ren "%SYSTEMROOT%\SoftwareDistribution\Download" Download.bak
)
 
if exist "%SYSTEMROOT%\system32\Catroot2.bak" rmdir /s /q "%SYSTEMROOT%\system32\Catroot2.bak"
if exist "%SYSTEMROOT%\system32\Catroot2" (
    attrib -r -s -h /s /d "%SYSTEMROOT%\system32\Catroot2"
    ren "%SYSTEMROOT%\system32\Catroot2" Catroot2.bak
)
 

:: Reset Windows Update policies
reg delete "HKCU\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /f
reg delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\WindowsUpdate" /f
reg delete "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /f
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\WindowsUpdate" /f
gpupdate /force


:: Reset the BITS service and the Windows Update service to the default security descriptor
sc.exe sdset bits D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWLOCRRC;;;AU)(A;;CCLCSWRPWPDTLOCRRC;;;PU)
sc.exe sdset wuauserv D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWLOCRRC;;;AU)(A;;CCLCSWRPWPDTLOCRRC;;;PU)


:: Reregister the BITS files and the Windows Update files
cd /d %windir%\system32
regsvr32.exe /s atl.dll
regsvr32.exe /s urlmon.dll
regsvr32.exe /s mshtml.dll
regsvr32.exe /s shdocvw.dll
regsvr32.exe /s browseui.dll
regsvr32.exe /s jscript.dll
regsvr32.exe /s vbscript.dll
regsvr32.exe /s scrrun.dll
regsvr32.exe /s msxml.dll
regsvr32.exe /s msxml3.dll
regsvr32.exe /s msxml6.dll
regsvr32.exe /s actxprxy.dll
regsvr32.exe /s softpub.dll
regsvr32.exe /s wintrust.dll
regsvr32.exe /s dssenh.dll
regsvr32.exe /s rsaenh.dll
regsvr32.exe /s gpkcsp.dll
regsvr32.exe /s sccbase.dll
regsvr32.exe /s slbcsp.dll
regsvr32.exe /s cryptdlg.dll
regsvr32.exe /s oleaut32.dll
regsvr32.exe /s ole32.dll
regsvr32.exe /s shell32.dll
regsvr32.exe /s initpki.dll
regsvr32.exe /s wuapi.dll
regsvr32.exe /s wuaueng.dll
regsvr32.exe /s wuaueng1.dll
regsvr32.exe /s wucltui.dll
regsvr32.exe /s wups.dll
regsvr32.exe /s wups2.dll
regsvr32.exe /s wuweb.dll
regsvr32.exe /s qmgr.dll
regsvr32.exe /s qmgrprxy.dll
regsvr32.exe /s wucltux.dll
regsvr32.exe /s muweb.dll
regsvr32.exe /s wuwebv.dll
netsh winsock reset
netsh winsock reset proxy

:: Set the startup type as automatic
sc config wuauserv start= auto
sc config bits start= auto
sc config DcomLaunch start= auto

:Start
net start bits
net start wuauserv
net start cryptsvc

:: Restart computer
cls
echo It is required to restart the computer to finish resetting Windows Update.
echo.
echo Please save and close anything open now, before the computer is restarted.
echo.
pause
echo.
echo.
echo.
echo *** Restart computer now. ***
echo.
pause
shutdown /r /f /t 0

Now exit Notpad and save the file name as anything you want but change the extension from txt to BAT, I save it as: Reset-Reregister_Windows_Update_Components.bat

Right click on it, then choose Run as Admin, once it is done, reboot and see if the update works

 

Thanks a lot, I ran it, but unfortunately it didn't work.

 

No, and in this pc I don't use third part security softwares.

 

Yes but in this case no, @blacknight has three partitions.

Not the whole disk just the first active partition where Windows sits and boots.
Just do a high level format for that partition.
Do not do a low or high level format or wipe to the whole disk. Again just the partition where Windows reside.

Btw, did you already try an in-place upgrade as @Brummelchen suggested? This way you won't lose settings or installed applications.

https://learn.microsoft.com/en-us/troubleshoot/windows-server/deployment/repair-or-in-place-upgrade
https://www.techtarget.com/searchenterprisedesktop/tip/Use-an-in-place-upgrade-to-repair-Windows-10
https://www.makeuseof.com/in-place-upgrade-windows-11/
https://www.elevenforum.com/t/repair-install-windows-11-with-an-in-place-upgrade.418/

 

Yes, I tried before beginning this thread, but every time I tried the operation aborted, and it said to me " An error occurred, impossible to complete the operation "

 

Then a clean installation is the only solution. If you need to, make use of a partition manager for better results.