AIM toolkit

On Windows 10.
I uninstalled original ImDisk 20250206
How to install this ImDisk 3.0

 

net stop ImDIsk
net stop AWEAlloc
then replace the files of the old one and
net start ImDIsk

 

I still don't get it. I don't have such files to overwrite. As I already said, I uninstalled ImDisk.

 

Ok here is a full packet: https://github.com/DavidXanatos/ImDisk/releases/download/v3.0.0/ImDisk3.0_Full.zip

 

or i am wrong, will sign it in the next release as well then

 

@DavidXanatos Windows 11 24H2 ok but on Windows 10 22H2:

Windows could not start the ImDisk Virtual Disk Driver Helper
service on Local Computer.
Error 1053: The service did not respond to the start or control
request in a timely fashion.

 

is the msvc runtime instaled:
x86: https://aka.ms/vs/17/release/vc_redist.x86.exe
x64: https://aka.ms/vs/17/release/vc_redist.x64.exe

 

https://sourceforge.net/p/aim-toolkit/blog/

Now what should I for the toolkit as well?

 

Thanks, I forgot to install the 2015-2022 one after reverting to a clean checkpoint.

ImDisk Toolkit Plus

 

https://streamable.com/bpk9rc

 

@Mr.X Run as admin?

 

Yes, both modes as you can see it in the video.

 

@Mr.X Try installing via CMD running as administrator.

cd /d "path"
install.cmd

 

Is there a "C:\Windows\system32" path in cmd > echo "%PATH%" output? If not, your environmental variables are corrupted or there is another problem with your system.

 

Yes it's there.

How do you explain I'm still able to install ImDiskTk20250206 package from v77?
As soon as I uninstall it and then try to install David's package it does not work

 

@Mr.X Edit "install.cmd"

Find:
echo off

Replace with:
echo on

Then share the output.

 

Spoiler

Code:

Microsoft Windows [Version 10.0.19045.5247]
(c) Microsoft Corporation. All rights reserved.

D:\Desktop\ImDisk3.0_Full>install.cmd

D:\Desktop\ImDisk3.0_Full>setlocal

D:\Desktop\ImDisk3.0_Full>pushd "D:\Desktop\ImDisk3.0_Full\"

D:\Desktop\ImDisk3.0_Full>title ImDisk Virtual Disk Driver setup

D:\Desktop\ImDisk3.0_Full>echo ImDisk Virtual Disk Driver setup
ImDisk Virtual Disk Driver setup

D:\Desktop\ImDisk3.0_Full>echo.


D:\Desktop\ImDisk3.0_Full>set IMDISK_TOTAL_DEVICES=0

D:\Desktop\ImDisk3.0_Full>set IMDISK_VALID_DEVICES=0

D:\Desktop\ImDisk3.0_Full>set IMDISK_PENDING_REMOVAL_DEVICES=0

D:\Desktop\ImDisk3.0_Full>if exist "C:\Windows\system32\imdisk.exe" (for /F %a in ('imdisk -l -n | find /v /i "No"') do call :addline "%a" )
'imdisk' is not recognized as an internal or external command,
operable program or batch file.

D:\Desktop\ImDisk3.0_Full>if 0 GTR 0 (
echo Number of existing ImDisk virtual disks: 0
 echo.
 if "" == "1" (
echo Please dismount all existing ImDisk virtual disks before upgrade!
 echo.
)  else (
.\msgboxw.exe "Please dismount all existing ImDisk virtual disks before upgrade!" 16 "ImDisk Virtual Disk Driver setup"
 start "" "C:\Windows\system32\control.exe" "C:\Windows\system32\imdisk.cpl"
)
 popd
 endlocal
 goto :eof
)

D:\Desktop\ImDisk3.0_Full>echo Number of existing ImDisk virtual disks: 0
Number of existing ImDisk virtual disks: 0

D:\Desktop\ImDisk3.0_Full>echo.


D:\Desktop\ImDisk3.0_Full>if 0 == 0 (
"C:\Windows\system32\net.exe" stop imdsksvc
 "C:\Windows\system32\net.exe" stop awealloc
 "C:\Windows\system32\net.exe" stop imdisk
 if exist "C:\Windows\system32\taskkill.exe" "C:\Windows\system32\taskkill.exe" /F /IM imdsksvc.exe
)
The ImDisk Virtual Disk Driver Helper service is not started.

More help is available by typing NET HELPMSG 3521.

The AWE Memory Allocation Driver service is not started.

More help is available by typing NET HELPMSG 3521.

The ImDisk Virtual Disk Driver service is not started.

More help is available by typing NET HELPMSG 3521.

ERROR: The process "imdsksvc.exe" not found.

D:\Desktop\ImDisk3.0_Full>"C:\Windows\system32\rundll32.exe" setupapi.dll,InstallHinfSection DefaultInstall 132 .\imdisk.inf

D:\Desktop\ImDisk3.0_Full>if errorlevel 1 (
if not "" == "1" .\msgboxw.exe "Setup failed. Please try to reboot the computer and then try to run the setup package again." 16 "ImDisk Virtual Disk Driver setup"
 popd
 endlocal
 goto :eof
)

D:\Desktop\ImDisk3.0_Full>set IMDISK_START_FAILED=1

D:\Desktop\ImDisk3.0_Full>if 0 == 0 (
set IMDISK_START_FAILED=0
 net start imdsksvc   || set IMDISK_START_FAILED=1
 net start awealloc   || set IMDISK_START_FAILED=1
 net start imdisk   || set IMDISK_START_FAILED=1
)
'net' is not recognized as an internal or external command,
operable program or batch file.
'net' is not recognized as an internal or external command,
operable program or batch file.
'net' is not recognized as an internal or external command,
operable program or batch file.

D:\Desktop\ImDisk3.0_Full>if not "" == "1" (if 1 == 0 (.\msgboxw.exe "Setup finished successfully. Open ImDisk Virtual Disk Driver applet in Control Panel or use imdisk command line to manage your virtual disks!" 0 "ImDisk Virtual Disk Driver setup" )  else (.\msgboxw.exe "Setup finished, but drivers or services could not start. Please try to reboot the computer and then try to run the setup package again." 16 "ImDisk Virtual Disk Driver setup" ) )

D:\Desktop\ImDisk3.0_Full>popd

D:\Desktop\ImDisk3.0_Full>endlocal

D:\Desktop\ImDisk3.0_Full>goto :eof

D:\Desktop\ImDisk3.0_Full>

 

@Mr.X Try the code below. I have added full path to all commands.

Spoiler: install.cmd

Code:

@echo off

setlocal

pushd "%~dp0"

title ImDisk Virtual Disk Driver setup

echo ImDisk Virtual Disk Driver setup
echo.

set IMDISK_TOTAL_DEVICES=0
set IMDISK_VALID_DEVICES=0
set IMDISK_PENDING_REMOVAL_DEVICES=0

if exist "%SystemRoot%\system32\imdisk.exe" (
  for /f %%a in ('%SystemRoot%\system32\imdisk.exe -l -n ^| find /v /i ^"No^"') do call :addline "%%a"
)

if %IMDISK_VALID_DEVICES% GTR 0 (
  echo Number of existing ImDisk virtual disks: %IMDISK_VALID_DEVICES%
  echo.
  if "%IMDISK_SILENT_SETUP%" == "1" (
    echo Please dismount all existing ImDisk virtual disks before upgrade!
    echo.
  ) else (
    .\msgboxw.exe "Please dismount all existing ImDisk virtual disks before upgrade!" 16 "ImDisk Virtual Disk Driver setup"
    start "" "%SystemRoot%\system32\control.exe" "%SystemRoot%\system32\imdisk.cpl"
  )
  popd
  endlocal
  goto :eof
)

echo Number of existing ImDisk virtual disks: %IMDISK_TOTAL_DEVICES%
echo.
if %IMDISK_TOTAL_DEVICES% == 0 (
  "%SystemRoot%\system32\net.exe" stop imdsksvc
  "%SystemRoot%\system32\net.exe" stop awealloc
  "%SystemRoot%\system32\net.exe" stop imdisk
  if exist "%SystemRoot%\system32\taskkill.exe" "%SystemRoot%\system32\taskkill.exe" /F /IM imdsksvc.exe
)

"%SystemRoot%\system32\rundll32.exe" setupapi.dll,InstallHinfSection DefaultInstall 132 .\imdisk.inf

if errorlevel 1 (
  if not "%IMDISK_SILENT_SETUP%" == "1" .\msgboxw.exe "Setup failed. Please try to reboot the computer and then try to run the setup package again." 16 "ImDisk Virtual Disk Driver setup"
  popd
  endlocal
  goto :eof
)

set IMDISK_START_FAILED=1
if %IMDISK_TOTAL_DEVICES% == 0 (
  set IMDISK_START_FAILED=0
  "%SystemRoot%\system32\net.exe" start imdsksvc || set IMDISK_START_FAILED=1
  "%SystemRoot%\system32\net.exe" start awealloc || set IMDISK_START_FAILED=1
  "%SystemRoot%\system32\net.exe" start imdisk || set IMDISK_START_FAILED=1
)

if not "%IMDISK_SILENT_SETUP%" == "1" (
  if %IMDISK_START_FAILED% == 0 (
   .\msgboxw.exe "Setup finished successfully. Open ImDisk Virtual Disk Driver applet in Control Panel or use imdisk command line to manage your virtual disks!" 0 "ImDisk Virtual Disk Driver setup"
  ) else (
   .\msgboxw.exe "Setup finished, but drivers or services could not start. Please try to reboot the computer and then try to run the setup package again." 16 "ImDisk Virtual Disk Driver setup"
  )
)

popd

endlocal

goto :eof

:addline

"%SystemRoot%\system32\imdisk.exe" -l -u %~1 > nul 2>&1

if errorlevel 1 (
  set /a IMDISK_PENDING_REMOVAL_DEVICES=%IMDISK_PENDING_REMOVAL_DEVICES% + 1 > nul
) else (
  set /a IMDISK_VALID_DEVICES=%IMDISK_VALID_DEVICES% + 1 > nul
)

set /a IMDISK_TOTAL_DEVICES=%IMDISK_TOTAL_DEVICES% + 1 > nul

goto :eof

 

I don't why is this getting so complicated...
I think I'm going to stop here.
Thanks anyway @busy

 

I have repackaged the latest imdisk installer: https://github.com/DavidXanatos/ImDisk/releases/download/v3.0.0/ImDiskTK.zip
also the script fails with an error message when the required MSVC runtime is not present

 

What's the change?
I see the same old deviodrv.sys driver signed by Lagerkvist Teknisk Rådgivning i Borås HB

 

Yes I wont bother my friend with the cert with re signing the drivers when i havn't made any new changes deviodrv.sys is usual not used and not changed
I only changed imdisk.sys and the versions trings in the unsigned usermode components

 

Installed on top of the last original version on Windows 10 x64. Everything seems correct.
Is the version reflected in control panel (20250206) supposed to be the same as yours?

 

Reading this thread is really astounding...

So, only imdisk.sys is changed, but you still changed other files and introduced a dependence to some MSVC runtime.
You have changed an issue by another.

You only provide the 64-bit version of the driver, but modify the Toolkit package designed for both 32 and 64-bit systems.

I could have do it myself, if this is so helpful, but I don't understand what you are doing.
You could say that your fix only apply to Windows 11, and therefore providing the 32-bit driver is useless, but are you sure about that? What about all the other incompatibilities that may be related?
Anyway, I will not make a new release of ImDisk Toolkit without a 32-bit driver.

By the way, signing user mode executables is useful against antiviruses, which are always an issue for this kind of tool.