Image For Windows

Ok.

Today i have bought it and are trying things out even more. One thing, is it possible to inactivate, remove, the frame that comes up when rebooting for restore from the main Gui, that one that gives 4 alternatives - abort, retry, cancel and reboot.

It really obstructs the automaticity. It should of course reboot directly.



Another thing, yesterday i could restore after having added that function to windows RE and when getting there i did everything manually, today, it always ask for licens and name. How do i get rid of this?

 

That should not happen. Did you download your purchased version of Image for Windows from this site?

https://www.terabyteunlimited.com/product-download.php

I'd uninstall and reinstall.

 

I got a link from them togheter with the license info etc, downloadewd from there. I have uninstalled reinstalled several times, same same. I shall uninstall again and try your link.

After having put in my license from the first start of the program i thought it would suffice so i where surprised when that happened in reboot environment.

 

OK. It's strange. Have a look at ifw.ini in...

C:\Program Files (x86)\TeraByte Drive Image Backup and Restore Suite

Does it contain your key and name? If so...
Copy ifw.ini to...

C:\Program Files (x86)\TeraByte Drive Image Backup and Restore Suite\tbwinre

The wim will need to be rebuilt. Let me think about this. Are you using a UEFI system?

 

Installed anew and are building the recovery environments right now.

Shall boot in to recovery after that to see if it has changed. Otherwise i will try your suggestion.

Yes, Uefi. W10 64 Home. Latest build.

 

My surname contains an ö, and that is as a strange figure instead in the licens info that show up when creating the wim restore environment. Maybe that is it. It is pretty usuall that i have to spell it with an o in a lot of other english speaking situations. I will try that also.

 

Does the Name supplied by TeraByte contain that letter?

 

Changing that figure did it. Thanks.
I did not come to think of it until you mentioned the above info. Thanks again.

Another thing, how do i know if the program is doing a differential or incremental? After reading the manual it did not get much clearer since it described the same move for both.

 

Yes. So it is a bit odd that it was changed in just that frame, only. But else was ok in the rest of the program.
But anyway, fixed now.

 

Differential and Incremental are both Changes Only backups...

https://www.wilderssecurity.com/thr...incremental-differential.444053/#post-3067708

 

Lets see if i got it right. After having done a full, i tick changes only when doing a "new backup" and get a smaller one, when doing yet another i tick the full if i want a differential and tick the "new backup" if i want a incremental. On and on and on.

 

Correct.

Do a Full backup and choose "Speed up Changes Only Backup" in Options.
The first Changes Only backup is a Differential.
When you do the next Changes Only backup it will be...
Differential if it's based on the Full backup
Incremental if it's based on the previous Changes only backup

When creating Differential backups you don't need to select "Speed up Changes Only Backup"
When creating Incremental backups you do need to select "Speed up Changes Only Backup"

 

If you intend to use Incrementals, select "Speed up Changes Only Backup" when doing the first Changes Only backup. It will speed up the creation of the next Changes Only backup.

 

Thank you the man from "down under".

Speed in backups is not an item for me only in restores and restores from "Diffs" usually are faster. Even in IFW i guess.

I tried your suggestion yesterday with restoring with Linux boot media but it was so much ticking in the recovery environment that i abandoned it thinking; this will be slow. Any suggestions on how i should do to get the fastest restores with, well - Linux... i guess.

 

What are your restore set up that gives you that fast restores, besides having a powerfull Pc i guess?

 

There are a couple more clicks in IFL than IFW. I hadn't noticed before.
My clicks in IFL. I select the item with the mouse and then press Enter on the keyboard. Two handed job.

Restore
Normal
File (Direct)
Linux
Select Drive
Browse to image
Single Pass
Linux
Select Target
Options... Write Changed Sectors Only (for SSDs). Tick in Reboot when Completed.
Start

Are you doing multi or single partition backups/restores?

 

Multi - bootpartition, reserved, C: and the recovery partition.

And Linux restores can only be done wtih usb etc?

 

Yes, I do 4 partition backups/restores too.

IFL can run from USB, optical media, IFL partition and a Linux OS partition.

Edit... I have IFL installed in Linux Mint. Multi-booting. It can backup/restore other OS partitions but because there is no locking mechanism in Linux (no VSS or PHYLock), you can't backup the running Linux partition.

 

Just my two cents, cause, ya know, you asked for it, but I do a full image every week and then differential images created daily. All of this is done using a script on a scheduler. I stay away from incremental images because that's just one less thing that could possibly go wrong. Maybe you can get some use out of it.

Code:

@echo off

:: Copyright (C) 2011-2012, TeraByte Unlimited.  All rights reserved.
:: version 1.2

:: This batch file maintains multiple iterations of a particular backup.  Each
:: time the batch file is run, a backup will be created. The filename will
:: include the date and time. For example, the first time the batch file is run,
:: <file name>_2010-04-18-2315__FULL.tbi will be created.  On the next run,
:: <file name>_2010-04-19-2315__FULL.tbi will be created. (Assuming it's run the
:: next day at the same time.) Once the number of backups reaches the number
:: specified, the oldest backup (or backup set) is deleted.
::
::
:: There are several settings you need to specify below.
:: Each one is preceded by the "set" command.

:: ---------------------------------------------------------------------------

:: Specify the folder where backup files will be saved. In all cases, omit the
:: trailing backslash, even for root directories (e.g. C: or D:). Folder
:: path can include spaces.
::
:: A UNC path can also be specified for this variable. NOTE: Make sure the share
:: is accessible or IFWRotate and/or Image for Windows may not function as expected.
:: If necessary, use the TBILogin variable below to specify the network share
:: login details. If IFWRotate cannot access the path it will be unable to count the
:: previous image backups, which will result in only Full images being created and
:: no images being deleted. In this case, it may be necessary to add credentials
:: for the share to the user account running IFWRotate.
::
:: Example: set TBIBase=D:\My Backups
::
:: Example: set TBIBase=\\server\backups\mybackups

set TBIBase=D:\Backups\System



:: Specify the desired backup filename below. In all cases, omit
:: the file extension. Filename can include spaces. This is the "base"
:: filename used for creating the Full and Differential filenames.
::
:: Backup images will have the same "base" name as the specified TBIName value
:: with the date, time, and "__FULL" appended (for Full images) or "_DIFF_", date,
:: and time appended (for Differential images).
::
:: Created Full image filename example: WorkComputer_2010-04-20-1754__FULL.tbi
::
:: Created Differential image filename example: WorkComputer_2010-04-20-1754_DIFF_2010-04-21-1754.tbi
::
:: Example: set TBIName=WorkComputer

set TBIName=System



:: Specify the parameters that should be used by IFW below. This is
:: where you specify the source drive and partition for the backup. Do not
:: include the "/f" option. It will be included automatically.
::
:: Note: If you need to use the Image for Windows "/login" option to access a network share,
:: use the TBILogin script variable below instead of specifying /login here.
::
:: Example: set TBIParms=/b /d:w0@0x1

set TBIParms=/b /d:w2@0x1,0x2,0x3,0x4,0x5 /opw:"PASSWORD" /log:0 /comp:12 /min /enc:3 /nt /geoa2k /hash /usemd



:: Specify the path to Image for Windows (imagew64.exe).
:: Note: Set this path only if not using the default installation path.
:: Do not include a trailing backslash. Do not include any spaces before or after the equals sign.
:: Omit quotation marks and the trailing backslash.
::
:: Example: set TBIPath=C:\Program Files (x86)\TeraByte Drive Image Backup and Restore Suite

set TBIPath=C:\Program Files\IFW



:: Specify the maximum number of Full image files to be saved. The oldest
:: Full image file (along with any associated Differential images) will be
:: deleted when this value is exceeded. Number must be between 2 and 99.
::
:: Note: If the number of existing backup sets (Fulls or Fulls + Differentials) exceed
:: the number specified, the older sets will be deleted when a new Full is created.
:: This may result in multiple sets being deleted. For example, if you had a previous
:: maximum of 7 and changed it to 3, the oldest sets will be deleted to bring
:: the count down to the new maximum of 3 when a new Full is created.
::
:: Example: Set TBIMaxFullCnt=4

set TBIMaxFullCnt=10



:: Specify the maximum number of Differential image backups to be created for
:: each Full backup. A setting of 0 (zero) will create only Full image backups.
:: If you want to create Differential backups, set the value to 1 or higher (max. 99).
::
:: Example: set TBIMaxDiffCnt=6

set TBIMaxDiffCnt=6



:: Specify any parameters needed when creating a Differential backup. Don't
:: include the "/b", "/base", or "/f" options as those are automatically
:: included. For example, you may want to verify the image after it's created.
::
:: Note: If you need to use the Image for Windows "/login" option to access a network share,
:: use the TBILogin script variable below instead of specifying /login here.
::
:: Example: set TBIDifParms=/v
::

set TBIDifParms=/opw:"PASSWORD" /log:0 /comp:12 /min /enc:3 /nt /geoa2k /hash /usemd



:: Specify the network login details (if needed to access a network share). Do not set
:: if network login is not required.
::
:: If you include the login details here, don't include them in TBIParms or TBIDifParms.
:: See the Image for Windows manual for details using the /login parameter.
::
:: Note: When this variable is used the script must be run with administrator privileges.
::
:: Example: set TBILogin=/login:"\\server\share*username*password"
:: Example: set TBILogin=/login:"\\BackupServer\Win7Backups*JohnSmith*mypassword"

set TBILogin=



:: ====================================================
:: Command line options for this script file
:: ====================================================
::
:: /f   Forces a new Full image to be created. Rotation rules for the
::      maximum number of Full images will still be enforced.
::
:: /d   Forces a new Differential image to be created. Using this option
::      will create a Differential image even if it will exceed the maximum
::      number specified.
::
::      Note: The Differential image will be based on the newest Full image.
::      If no Full image exists, a Full image will be created instead.
::
::

:: ###########################################################################
:: #
:: # NO CHANGES SHOULD BE NEEDED PAST THIS POINT
:: #
:: ###########################################################################

:: Check for Windows 2000 or later

if not "%OS%"=="Windows_NT" goto :NoWin

:: ---------------------------------------------------------------------------

:: Init vars

setlocal enableextensions enabledelayedexpansion

set Error=X
set Number1=X
set Number2=X
set TBICmd=X
set TBIOldest=X
set TBINewest=X

if %TBIMaxFullCnt% LSS 2 set /a TBIMaxFullCnt=2
if %TBIMaxFullCnt% GTR 99 set /a TBIMaxFullCnt=99
if %TBIMaxDiffCnt% LSS 0 set /a TBIMaxDiffCnt=0
if %TBIMaxDiffCnt% GTR 99 set /a TBIMaxDiffCnt=99

if not defined TBIBase echo No TBIBase parameter supplied.  Please edit: %0 & goto :End
if not defined TBIName echo No TBIName parameter supplied.  Please edit: %0 & goto :End
if not defined TBIParms echo No TBIParms parameter supplied.  Please edit: %0 & goto :End
if not defined TBIMaxFullCnt echo No TBIMaxFullCnt parameter supplied.  Please edit: %0 & goto :End
if not defined TBIMaxDiffCnt echo No TBIMaxDiffCnt parameter supplied.  Please edit: %0 & goto :End

:: ---------------------------------------------------------------------------

if "%TBIPath:~0,1%"==" " (set TBIPath=)
if "%TBIPath%"=="" if "%PROCESSOR_ARCHITECTURE%"=="AMD64" set TBIPath=C:\Program Files (x86)\TeraByte Drive Image Backup and Restore Suite
if "%TBIPath%"=="" set TBIPath=C:\Program Files\TeraByte Drive Image Backup and Restore Suite
if not exist "%TBIPath%\imagew64.exe" echo Unable to find 'imagew64.exe' in the following path: & echo %TBIPath% & echo. & echo Please edit %0 and check TBIPath value. & goto :End

:: ---------------------------------------------------------------------------

:: Log into network share

if "%TBILogin:~0,1%"==" " (set TBILogin=)
if defined TBILogin start "" /min /wait "%TBIPath%\imagew64.exe" %TBILogin% /log:0 /quit

:: Get Full image file counts

set /a Number1=0
if exist "%TBIBase%\%TBIName%_*__FULL.tbi" for /f "delims=" %%a in ('dir "%TBIBase%\%TBIName%_*__FULL.tbi" /o-d /b /p /-p /w /-w') do (set TBIOldest=%%a) & (set /a Number1=!Number1!+1) & (if "!TBINewest!"=="X" set TBINewest=%%a)
set TBIFullCnt=%Number1%
echo.
echo Number of Full images found in set: %TBIFullCnt%
if "%TBINewest%"=="X" set TBINewest=(none)
if "%TBIOldest%"=="X" set TBIOldest=(none)
echo Oldest Full image set found: %TBIOldest%
echo Newest Full image set found: %TBINewest%

:: Get Diff image file counts for newest set

set TBINewest=%TBINewest:~0,-10%
set /a Number1=0
if exist "%TBIBase%\%TBINewest%_DIFF*.tbi" for /f %%a in ('dir "%TBIBase%\%TBINewest%_DIFF*.tbi" /o-d /b /p /-p /w /-w') do (set /a Number1=!Number1!+1)
set TBIDiffCnt=%Number1%
echo.
echo Number of Differential images found in newest Full set: %TBIDiffCnt% of %TBIMaxDiffCnt%

:: Check which type of backup (Full or Diff) needs to be created

if /i "%1"=="/f" goto :CreateFull
if %TBIFullCnt%==0 goto :CreateFull
if /i "%1"=="/d" goto :CreateDiff
if %TBIDiffCnt% LSS %TBIMaxDiffCnt% goto :CreateDiff

goto :CreateFull

:CreateDiff

echo.
echo Create Differential Image
echo -- Running command: "%TBIPath%\imagew64.exe" /b %TBIDifParms% /base:"%TBIBase%\%TBINewest%__FULL" /f:"%TBIBase%\%TBINewest%_DIFF_$~YYYY$-$~MM$-$~DD$-$~HHMM$"
start "" /wait "%TBIPath%\imagew64.exe" /b %TBIDifParms% /base:"%TBIBase%\%TBINewest%__FULL" /f:"%TBIBase%\%TBINewest%_DIFF_$~YYYY$-$~MM$-$~DD$-$~HHMM$"
goto :PostBkup

:CreateFull

if %TBIFullCnt% LSS %TBIMaxFullCnt% goto :CreateFullImage
echo.
echo Number of Full images will exceed %TBIMaxFullCnt%.
echo Deleting oldest Full image set: %TBIOldest%
del "%TBIBase%\%TBIOldest%"
set TBIOldest=%TBIOldest:~0,-10%
if exist "%TBIBase%\%TBIOldest%_DIFF*.tbi" del "%TBIBase%\%TBIOldest%_DIFF*.tbi"
if exist "%TBIBase%\%TBIOldest%__FULL.#*" del "%TBIBase%\%TBIOldest%__FULL.#*"
:: Check if additional old backup sets need deleted
set /a Number1=0
if exist "%TBIBase%\%TBIName%_*__FULL.tbi" for /f "delims=" %%a in ('dir "%TBIBase%\%TBIName%_*__FULL.tbi" /o-d /b /p /-p /w /-w') do (set TBIOldest=%%a) & (set /a Number1=!Number1!+1)
set TBIFullCnt=%Number1%
if %TBIFullCnt% LSS %TBIMaxFullCnt% goto :CreateFullImage
goto :CreateFull


:CreateFullImage

echo.
echo Create Full Image
echo -- Running command: "%TBIPath%\imagew64.exe" %TBIParms% /f:"%TBIBase%\%TBIName%_$~YYYY$-$~MM$-$~DD$-$~HHMM$__FULL"
start "" /wait "%TBIPath%\imagew64.exe" %TBIParms% /f:"%TBIBase%\%TBIName%_$~YYYY$-$~MM$-$~DD$-$~HHMM$__FULL"

forfiles -p D:\Backups\System\  -m *DIFF*.* /D -6 /C "cmd /c del /q @path"

goto :PostBkup


:: ---------------------------------------------------------------------------

:PostBkup

set Error=%ERRORLEVEL%

echo.
echo #########################################
if not "%Error%"=="0" echo # The following error was reported: %Error%
if "%Error%"=="0" echo # No errors were reported.
echo #########################################
echo.

goto :End


:: ---------------------------------------------------------------------------

:NoWin

echo.
echo Windows 2000 or later is required for this script.
echo.
goto :End


:: ---------------------------------------------------------------------------

:End

set Error=
set Number1=
set Number2=
set TBIFullCnt=
set TBIDiffCnt=
set TBICmd=
set TBIOldest=
set TBINewest=

endlocal

set TBIBase=
set TBIName=
set TBIParms=
set TBIPath=
set TBIMaxFullCnt=
set TBIMaxDiffCnt=
set TBIDifParms=
set TBILogin=

attrib +h D:\Backups\System\*.#_# /s /d

attrib +h D:\Backups\System\*.@0 /s /d

attrib +h D:\Backups\System\*.#0 /s /d

:: End of batch script

echo Done!

 

Ok. But i do not see how this gives you fast restores.

 

Is it okay to say I don't know? I mean, everything I'm backing up is from an SSD to a platter drive. The data I'm backing up only amounts to about 50gbm, w/ image file being roughly 21gb. Play around with your image compression settings. I found that /comp:12 works optimally for me. I am u sing a Samsung 860 EVO SSD. Other than that, I'm not doing anything all that special.

 

I will have a go at it again.
I have a small recovery partition on a external SSD disc that is used just as an usb. I guess that will suffice as a IFL partition?

 

Ok, thanks for the tip!

How do you restore then, mainly, RE or PE, from within IFW or from boot meny, usb - etc etc?

 

Now that they've simplified the auto-restore process, I always use auto-restore into RE.

 

I only use Full and Differential.
I also use the IFWRotate script. It's a great script.