Running IFL on BIOS without a Boot Disk

Here are my lines...

set TARGETDIR=C:\IFLBOOT

set IFLFILE=ifl.iso

set IFLDIR="D:\Storage\Keep\S to Z\TeraByte apps\TeraByte downloads bought\Version 2 final all\298\ifl_nonet_en_gui"

set IFLPK=removed from this script

set IFLBIN=ifl

The third one will be different in your script.

 

Okay, going to check mine and come back to edit this post.

Edit-
I think I already found the problem. In the following path
C:\Program Files (x86)\TeraByte Unlimited\Image for Windows\V2\IFL

I've got this structure within:
So iflnet.iso is missing
http://i.imgur.com/F5OzWd8.png

 

In my case
D:\Storage\Keep\S to Z\TeraByte apps\TeraByte downloads bought\Version 2 final all\298\ifl_nonet_en_gui
contains ifl.iso

Your
C:\Program Files\TeraByte Unlimited\Image for Windows\V2\IFL
should contain iflnet.iso
so you line should be
set IFLFILE=iflnet.iso

Different from mine

I did mention earlier to download the non net version. (In your download area it is "Image for Linux V2.98 (GUI), (Without Networking))
You are using the Networking version so our lines "don't line up".

 

Files are missing from the folder you posted.

 

Yes now I see. Those are from Image for Windows V2.98 (GUI) with IFD-GUI, IFL-GUI, and IFU-CUI default installation.

 

Should be OK to use but you need iflnet.iso in that folder.

I use the non network IFL as it loads somewhat faster than the network IFL.

 

No luck. Something's wrong with this, I am tired now, but I have the idea thanks to you. Maybe tomorrow.

 

Try what I've been doing. Download the non net IFL and put it in a folder in your data partition. Then your lines will be almost identical to mine. The third line will differ. You are so close to the end.

 

One more question, there's no need to install Image for Windows to run IFL without a boot disk, right?

 

No, IFW isn't needed. But you do need the tbosdt folder to create IFLBOOT folder.

 

oh yeah tbosdts_pro folder, right. Thanks again Brian is 10:30 p.m. here and it was a long day so I'm going to bed lol
I appreciate a lot your help and maybe tomorrow I come back with good news. I just need to copy the right folders in the right paths and re-do my ini and bat files.

 

You are so close. It is something simple that is holding us up.

 

Yes I know, but you know lol
Now wife is calling
See you tomorrow, have a nice day there...

 

Rest assured also you are not misleading me or leading me astray, quite the opposite your help is priceless. Now I have a better understanding about this topic.

Edit- I need to schedule this IFL boot thing later today, I need to do it cause there's more work coming and have to be prepared.

 

I know you have a Legacy system. Bootfile should be used cautiously in a UEFI system as it can have unexpected results. It depends on your particular brand of UEFI.

 

Ok, got it.

 

In my test UEFI system, TBWinRE bootfile works and IFL bootfile doesn't.

 

Here's my new setup, unfortunately it still doesn't work:

C:\IFL\ifl_nonet_en_gui
C:\IFL\tbosdts_pro\iflsetup
C:\IFLBOOT

C:\IFL\tbosdts_pro\iflsetup\ifl.ini:

Code:

[Options]
TimeZone=MEX+6

[License]
ProductKey=XXXX-YYYY-ZZZZ

[BACKUP_DEFAULTS]
Compression=14
PostValidate=1

[RESTORE_DEFAULTS]
WriteMBR=1
RFT=1
PreValidate=0x1

C:\IFL\tbosdts_pro\iflsetup\ifl_boot.cfg:

Code:

## The options available to customize the IFL bootfile are shown below. The
## line starting with a single "#" should be edited (if necessary), and then
## uncommented by deleting the "#" at the beginning of the line.


## RUNSCRIPTS option: Uncomment and edit ONLY if you would like to execute
## one or more of the scripts in the ifl_scripts directory AUTOMATICALLY on
## boot. To execute more than 1 script, there must be a space between each
## two script names inisde the parenthesis, such as in this example:
## RUNSCRIPTS=(script1 script2 script3)
## Once booted from the disk, you will the contents of the ifl_scripts
## folder in the /tbu/scripts folder on the running boot disk.
RUNSCRIPTS=(RESTORE.tbs)


## SSHD_START option: Uncomment ONLY if you want the sshd server started
## automatically on boot. The default is that it will NOT be started up on
## boot. If sshd is running, remote users can login to the IFL disk via an
## ssh session. A user name and password are always required for an ssh
## login. By default, the root account and password are available.
#SSHD_START="yes"


## HARDWARECLOCK option: Uncomment ONLY if your hardware clock is set to UTC
## Otherwise, it is assumed that your clock is set to local time (default)
#HARDWARECLOCK="UTC"


## TIMEZONE option: To set the timezone in the IFL Linux environment, you
## can uncomment one of the common timezones listed below, or refer to the
## zoneinfo.zip file in this folder to similarly specify other locations.
## If not specified, the timezone will be set to "UTC" by default.
#TIMEZONE="US/Eastern"
#TIMEZONE="US/Central"
#TIMEZONE="US/Mountain"
#TIMEZONE="US/Pacific"
#TIMEZONE="US/Hawaii"
#TIMEZONE="US/Alaska"

#TIMEZONE="Europe/London"
#TIMEZONE="Europe/Paris"
#TIMEZONE="Europe/Berlin"
#TIMEZONE="Europe/Moscow"
#TIMEZONE="Europe/Rome"
#TIMEZONE="Europe/Vienna"

#TIMEZONE="Asia/Hong_Kong"
#TIMEZONE="Asia/Shanghai"
#TIMEZONE="Asia/Seoul"
#TIMEZONE="Asia/Taipei"
#TIMEZONE="Asia/Tokyo"

C:\IFL\tbosdts_pro\iflsetup\setupifl.bat:

Code:

@echo off

::
:: TARGETDIR parameter must be set to a drive letter located on boot drive
:: (HD0). This directory is where the files needed to boot IFL will be
:: placed when setupifl.bat is executed. From this directory a batch file
:: can then be executed to boot into IFL.
::
set TARGETDIR=C:\IFLBOOT

::
:: IFLFILE should be set to the IFL ISO file name to use (iflnet.iso by
:: default). This file will be looked for at the path defined by the IFLDIR
:: parameter below, and will be used to copy IFL files from.
::
set IFLFILE=ifl.iso

::
:: IFLDIR defines the path where the IFL ISO file defined by the IFLFILE
:: parameter above can be found. The default value below is the default path
:: when when the IFW/IFD/IFL package is installed on 32-bit Windows.
::
set IFLDIR="C:\IFL\ifl_nonet_en_gui"

:: Uncomment the line below if IFW/IFD/IFL is installed on 64-bit Windows.
:: set IFLDIR="C:\Program Files (x86)\TeraByte Unlimited\Image for Windows\V2\IFL"

::
:: IFLPK is your IFL Product Key, required to run the registered version.
:: Example: set IFLPK=0000-1111-2222
:: If using trial version of IFL, leave this parameter set to default.
::
set IFLPK=XXXX-YYYY-ZZZZ

::
:: IFLBIN is the file name for the bootfile being created in the TARGETDIR
:: defined above. This is the file that bootfile.exe will boot in order to
:: boot into IFL from Windows. This filename will have a .bin extension
:: added automatically.
:: Example: set IFLBIN=ifl results in a bootfile named ifl.bin, and the batch
:: file created to boot from ifl.bin will be named run_ifl.bat
::
set IFLBIN=ifl


::-----------------------------------------------------------------------------

::
:: Setup name of windows version of TBOSDT (to support older releases)
::
set TBOSDT=tbosdtw.exe
if not exist ..\win\%TBOSDT% set TBOSDT=tbosdt.exe

::
:: verify directory and files
::
for %%i in (ifl_boot ifl_boot.cfg ifl_boot.tbs setupifl.bat ifl_scripts ..\win\bootfile.exe ..\win\%TBOSDT%) do if not exist %%i goto baddir
for %%i in (%ifldir%\%iflfile%) do if not exist %%i goto badifldir

::
:: create copy of original bootfile with specified file name
:: the file ifl_boot is the template bootfile
::
copy ifl_boot ifl_boot.tmp

::
:: copy iflnet.iso over from specified location
::
copy /y %ifldir%\%iflfile% %iflfile%

::
:: run the ifl_boot.tbs script and pass the Product Key and ISO file name
::
..\win\%TBOSDT% ifl_boot.tbs %iflpk% %iflfile%

::
:: setup target directory
::
if exist %targetdir%\. goto skipmd
md %targetdir% > nul
if not exist %targetdir%\. goto badmd
:skipmd
move /y ifl_boot.tmp %targetdir%\%iflbin%.bin >nul
copy /y ..\win\bootfile.exe %targetdir% >nul
echo %targetdir%\bootfile %targetdir%\%iflbin%.bin > %targetdir%\run_%iflbin%.bat
start %targetdir%
goto end

::
:: report errors
::
:badmd
echo Unable to create target directory %targetdir%
pause
goto end

:baddir
echo This batch file must be launched from the iflsetup folder, which must
echo be a sub-folder of tbosdts_pro. The following files are required to be
echo in the iflsetup folder:
echo ifl_boot
echo ifl_boot.cfg
echo ifl_boot.tbs
echo ifl_scripts (folder)
echo The following files are required to be in the tbosdts_pro\win folder:
echo tbosdtw.exe
echo bootfile.exe
pause
goto end

:badifldir
echo Unable to find the IFL ISO file.
echo Please check the IFLDIR and IFLFILE variables above
pause
goto end

:end

del %IFLFILE%
set IFLFILE=
set IFLINI=
set IFLPK=
set IFLDIR=
set TARGETDIR=
set TBOSDT=
set IFLBIN=

 

Are you double clicking setupifl.bat or Running as Admin? Needs double click.

Is the "win" folder inside the "tbosdts_pro" folder? win folder and iflsetup folder at same level?

Do you get an error message when you run setupifl.bat?

 

Right click runas admin.

Yes and yes.

Yes, this one within a cmd prompt:

Code:

This batch file must be launched from the iflsetup folder, which must
be a sub-folder of tbosdts_pro. The following files are required to be
in the iflsetup folder:
ifl_boot
ifl_boot.cfg
ifl_boot.tbs
ifl_scripts (folder)
The following files are required to be in the tbosdts_pro\win folder:
tbosdtw.exe
bootfile.exe

 

Damn it was the double click.
At last I could create it.

This is so ridiculous...

 

Don't worry. That baffled me too.

 

How am I supposed to run run_ifl.bat? Double click too?

 

Right click and Run as Admin. In Win10 you can double click but I can't recall if this works in earlier Windows.

 

Well I think by now I've learned the lesson on how to run Terabyte Unlimited scripts
Either double click or runas admin, a matter of trial/error for every time.